便利な使い方

• 一度に複数の空ファイルを作成する
1. ファイルメニュー → 新規作成
2. ファイルのタイプを選び
3. 新規ドキュメントの作成ダイアログの[名前]ボックスに、名前を ; で区切って入力

例）

a;b;c;d;e

4. または Ctrl + Enter で改行して入力

a b c d e

5. ファイルタイプが「テキスト文書」であれば、 a.txt b.txt c.txt d.txt e.txt が作成される。
• ファイルタイプで関連付けされていないアプリケーションを使用してファイルを開く
例えば、「FileShelf Plus 」でCtrl-Bを押して、バイナリエディタBzでファイルを開くには
1. ツールメニュー → オプションを選び
2. ツールタブを開く
3. タイトルとコマンドラインへ以下のように入力

	タイトル	コマンドライン
外部ツール1	Bz	"C:\Program Files\bz\Bz.exe" %1

4. ツールメニュー → キーボードカスタマイズを選び
5. ツール1のショートカットキーに「Ctrl-B」を割り当てる。
6. 「FileShelf Plus」でファイルを選択し、Ctrl-Bを押すと、Bzがそのファイルを開く。
• 秀丸のgrep機能(ファイルから文字列を検索)を簡単に使う
「FileShelf Plus 」でCtrl-Gを押して、grepを実行するには
1. ツールメニュー → オプションを選び
2. ツールタブを開く
3. タイトルとコマンドラインへ以下のように入力

	タイトル	コマンドライン
外部ツール1	grep	"C:\Program Files\Hidemaru\Hidemaru.exe" /g,"*.*",%Input%

ここでは「*.*」を指定しているため、全てのファイルを検索する。

「*.htm*」とすれば、検索するファイルは全てのhtmlファイルとなる。

4. ツールメニュー → キーボードカスタマイズ
5. ツール1のショートカットキーに「Ctrl-G」を割り当てる。
6. 「FileShelf Plus」で、検索したいフォルダを開き、Ctrl-Gを押すと、「文字列の入力」ダイアログが表示される。
7. ここで、検索したい文字列を入力し、[OK]をクリックすると、秀丸の grep が実行される。
• EmEditorのgrep機能を簡単に使う
「FileShelf Plus 」でCtrl-Gを押して、grepを実行するには
1. ツールメニュー→オプションを選び
2. ツールタブを開く
3. タイトルとコマンドラインへ以下のように入力

	タイトル	コマンドライン
外部ツール1	grep	"C:\Program Files\EmEditor3\EMEDITOR.EXE" /fi %Input% "%CurrentDirectory%\*.*"

4. ツールメニュー → キーボードカスタマイズ
5. ツール1のショートカットキーに「Ctrl-G」を割り当てる。
6. 「FileShelf Plus」で、検索したいフォルダを開き、Ctrl-Gを押すと、「文字列の入力」ダイアログが表示される。
7. ここで、検索したい文字列を入力し、[OK]をクリックすると、EmEditor の grep が実行される。
• ファイル名の変更でこんなことができます
1. ツールメニュー→オプション
2. フォルダ操作タブで「ファイル名をインプレイス編集」「クリックしてインプレイス編集」「インプレイス編集中に Downキーで次のファイル名 Upキーで前のファイル名をインプレイス編集 」チェックボックスを全てオンにすると
3. ファイル名をクリックして名前編集した後にDownキーを押すと、次のファイル名に移動してすぐに名前編集ができる状態になります。

マクロのサンプルをご紹介します

• 「Windows マシン」と「Linuxマシン」をシャットダウンするマクロ

// マクロファイル名 : autoshutdown.fsl
{
  if( YesnoBox("本当にシャットダウンしてもいいですか") != "YES" ) {
    stop;
  }

  SetId("xxxx");                   // LinuxマシンのユーザーID
  SetPassword("xxxxxxxx");         //              パスワード
  TelnetOpen("xxx.xxx.xxx.xxx");   // LinuxマシンのIPアドレス
  MacroExecute("unixlogin.fsl");   // このマクロでLinux にログイン

  TelnetSend("su - root\n");       // ログインできたら、スーパーユーザーに変身
  TelnetWait("Password: ");
  TelnetSend("xxxxxxxx\n");        // スーパーユーザーのパスワード送信
  TelnetWait("# ")
  TelnetSend("sync\n");            // ディスク書き出し
  TelnetWait("# ")
  TelnetSend("shutdown -h now\n"); // Linuxマシンをシャットダウン
  TelnetWait("# ")
  TelnetClose();                   // 一応クローズしておきます

  Poweroff();                      // Windows マシンをシャットダウンします
                                   // Poweroff()で電源が切れない場合は、
                                   // Shutdown()を使ってみてください

  exit;                            // 「FileShelf Plus」プロセスを終了します
}

// マクロファイル名 : unixlogin.fsl
{
  $prompt = "$ ";
again:
  if( GetId() == "" ) {
    InputBox($a,"User ID :");
    if( $a == "" ) {
        end;
    }
    SetId($a);
  }

  if( GetPassword() == "" ) {
    InputBox($a,"Password :");
    if( $a == "" ) {
        end;
    }
    SetPassword($a);
  }

  OpenConnectMessage("UNIX login...");
  SetTimer(60);
  while(1) {
    switch() {
      case("Last login:")
        break;
      case("login:")
        TelnetSend( GetId()+"\n");
        break;
      case("Password: ")
        TelnetSend( GetPassword()+"\n");
        break;
      case("Login incorrect")
        SetId("");
        SetPassword("");
        CloseMessage();
        goto again;
      case($prompt);
        TelnetSend("stty rows "+GetTermRows()+"\n");
        TelnetWait($prompt);
        TelnetSend("stty columns "+GetTermColumns()+"\n");
        TelnetWait($prompt);
        goto endlogin;
      case(TIMEOUT)
        TelnetClose();
        goto endlogin;
    }
  }
endlogin:
  KillTimer();
  CloseMessage();
}

• ホームページ更新サンプル

// マクロファイル名 : hpupdate.fsl
{
  FtpSetType("BIN");                  // バイナリモードを指定します
  SetId("xxxxxxx");                   // FTPサーバのユーザーID
  SetPassword("xxxxxxxx");            // FTPサーバのパスワード
                                      // FTPサーバをオープン
  if( FtpOpen("xxx.xxx.xxx.xxx") != TRUE ) {
    MessageBox("FTPオープン失敗");    // 失敗した場合は失敗メッセージ
    end;
  }
  ChDir("C:\My Documents\homepage");  // ホームページのファイルを置いているローカルフォルダの場所を指定
  FtpChDir("/html");                  // アップロード先の場所を指定
  FtpPut("home\","UPDATE");           // home フォルダ配下のファイルを全てアップロード
                                      // (名前に \ を付けると、フォルダとして扱います)
                                      // "UPDATE"モードを指定すると、新しいファイルのみアップロードします
  FtpClose();                         // アップロードが完了してクローズ
  MessageBox("ホームページ更新完了"); // 完了メッセージ
}

• Ftpフォルダリストで選択したファイルを Hidemarnet Explorer で編集する

// マクロファイル名 : hidenet.fsl
{
  $a=GetFirstSelectedUrlPath();
  while( $a != "" ) {
    ShellExecute ("C:\Program Files\Hidemaru\Hidemaru.exe",$a)
    $a=GetNextSelectedUrlPath();
  }
}

• フルパス名を指定してFtpサイトのファイルを見る

// マクロファイル名 : viewftpfile.fsl
// Ftpサイトのファイルをフルパス名を指定して見る
{
  $tmpdir="c:\work";
  InputBox($dir2,"フルパス名を入力");
  if( $dir2 == "" ) {
    end;
  }

  $n=0;
  $len=StrLength($dir2);
  while($n<$len) {
    if( StrMid($dir2,$n,1) == "/" ) {
        $last=$n;
    }
    $n=$n+1;
  }

  // ディレクトリとファイル名に分ける
  $dir = StrLeft( $dir2, $last);
  $last=$last+1;
  $file = StrMid( $dir2, $last);

  SetId("xxxxxxxx");                  // FTPサーバのユーザーID
  SetPassword("xxxxxxxx");            // FTPサーバのパスワード
  if( FtpOpen("xxx.xxx.xxx.xxx") != TRUE ) {
    MessageBox("FTPオープン失敗");    // 失敗した場合は失敗メッセージ
    end;
  }

  ChDir($tmpdir);
  FtpChDir($dir);
  FtpGet($file,"OVERWRITE");
  FtpClose();

  $text = StrAppend($tmpdir+"\"+$file);
  ViewText($text);
}

• 現在の日付で新しいフォルダを作成する

// マクロファイル名 : newfolderdate.fsl
{
  $FolderName = StrAppend ("%CurrentDirectory%\\"+GetDate());
  MkDir ($FolderName);
}

• 現在の日付と時間で新しいファイルを作成する

// マクロファイル名 : newtextdate.fsl
{
  $FileName = StrAppend ("%CurrentDirectory%\\"+GetDate()+" "+StrLeft(GetTime(),4)+".txt");
  OpenFile ($FileName,"WRITE");
  CloseFile();
  ViewText ($FileName);
}

• SQLの実行結果を見る(単純な問合せのサンプル)

// マクロファイル名 : sqlplus.fsl
// SQLの実行結果を見る
{
  $LogFile = "C:\Temp\sql.log";
  $a = FindFirstFile ($LogFile);
  if ( $a != "" ) {
    DeleteFile ($LogFile);
  }

  LogStart ($LogFile);
  SetId ("xxxxxxxx");
  SetPassword ("xxxxxxxx");
  TelnetOpen ("xxx.xxx.xxx.xxx");
  MacroExecute ("unixlogin.fsl");
  TelnetSend ("sqlplus xxxxxxxx/xxxxxxxx\n");
  TelnetWait ("SQL> ");
  TelnetSend ("set linesize "+GetTermColumns()+"\n");
  TelnetWait ("SQL> ");
  TelnetSend ("set pagesize 10000\n");
  TelnetWait ("SQL> ");
  TelnetSend ("select * from dual;\n");
  TelnetWait ("SQL> ");
  TelnetSend ("exit\n");
  TelnetClose();
  LogStop();
  ViewText ($LogFile);
}

• SQLの実行結果を見る (メンバーとの等価性をテストするサンプル)

// マクロファイル名 : sqlplus.fsl
// SQLの実行結果を見る
// メンバーとの等価性をテストするサンプル
{
  $LogFile = "C:\Temp\sql.log";
  $a = FindFirstFile ($LogFile);
  if ( $a != "" ) {
    DeleteFile ($LogFile);
  }

  LogStart ($LogFile);
  SetId ("xxxxxxxx");
  SetPassword ("xxxxxxxx");
  TelnetOpen ("xxx.xxx.xxx.xxx");
  MacroExecute ("unixlogin.fsl");
  TelnetSend ("sqlplus xxxxxxxx/xxxxxxxx\n");
  TelnetWait ("SQL> ");
  TelnetSend ("set linesize "+GetTermColumns()+"\n");
  TelnetWait ("SQL> ");
  TelnetSend ("set pagesize 10000\n");
  TelnetWait ("SQL> ");
  TelnetSend("select * from emp where name in (\n");

  // 値が列挙されたテキストファイルを開く
  OpenFile ("C:\Temp\list.txt","READ")
  $out="";
  $rc=1;
  while( $rc == 1 ) {
    $rc = GetsFile( $str );       // 1行読み込む
    $i = StrFind( $str, "\r\n");  // 末尾の改行コードを削除する
    if( $i >= 0 ) {
      $str = StrLeft( $str, $i);
    }

    if( $rc == 1 ) {              // 正常に読み込めた場合
      if( $out != "" ) {
        TelnetSend(",\n");
      }

      TelnetSend("'"+$str+ "'");
      $out = $str;
    }
    else {                        // ファイルの終端の場合
      TelnetSend(");\r\n");
    }
  }
  CloseFile();

  TelnetWait ("SQL> ");
  TelnetSend ("exit\n");
  TelnetClose();
  LogStop();
  ViewText ($LogFile);
}